Applicare uno schema XML a un documento Word 2007

Applicare uno schema XML a un documento Word 2007

< ?xml version="1.0"?>
 

< !-- Nome file: SchemaFattura.xsd -->

Tale schema è stato ripreso dal CD di un libro (purtroppo essi scarseggiano nella dotazione che dovrebbe accompagnare Word 2007 almeno nell’ed. italiana), modificandone campi e aggiungendone, ma senza cambiare il namespace http://www.w3.org/2001/XMLSchema altrimenti lo schema verrebbe rifiutato. Quindi lo si copi e incolli nel Blocco Note e lo si salvi in una cartella che andrà destinata a questo e ad altri schemi (senza poi modificarla!) col nome SchemaFattura.xsd.

La struttura del nostro schema è del tipo più semplice, sequenza (come indicato dal nodo xsd:sequence) ossia una serie di campi senza gerarchie. Insomma equivale a una normale tabella “classica”. Accenniamo che applicando tale schema a un file .XLM questo si presenterebbe dotato di tag del tipo seguente:

< NOME>Mario< /NOME>

< COGNOME>Bianchi< /NOME>

. . . . . .

< DESCRIZIONE>Cocomeri< /DESCRIZIONE>

< QUANT>123< /QUANT>

eccetera.

Schema XML in un documento Word

Vediamo invece come si usa uno schema XML in Word. Occorre anzitutto sincerarsi che la barra multifunzione contenga il quadro Sviluppo (provvedere, se occorre, con mosse che diamo per facili, altrimenti ricorrere al solito amico...), quindi in un nuovo documento Word si compiano le operazioni seguenti.

1. Scegliere Sviluppo > Struttura > Schema.
2. Nella finestra Modelli e aggiunte, pannello Schema XML, dare un clic su Aggiungi schema...
3. Navigare nel disco fino a “pescare” il nostro SchemaFattura.xsd.
4. Nella susseguente finestra Impostazioni schema digitare http://www.w3.org/2001/XMLSchema nella casella URI e Fattura nella casella Alias.
   
   
   
5. Si prepari un layout tipico (v. figura più avanti) comprendente in alto l’intestatario della fatturina con nome, cognome, indirizzo ecc. e, sotto, una tabella con campi intestati Descrizione, Quantità, Prezzo eccetera.
6. Si lanci di nuovo Sviluppo > Schema scegliendo il nostro Fattura (attivandone la casellina) e si dia l’OK. Compare sulla destra un pannello, inizialmente vuoto.
7. Per renderlo più “eloquente” si selezioni il punto del documento in cui si desidera inserire un campo, diciamo il primo carattere sotto “Spettabile”, il che farà comparire solo FATTURA nella lista in basso. Selezionandola si riceverà la richiesta se applicare lo schema all’intero documento o alla selezione. Conviene scegliere la seconda, che fa apparire i segnaposti FATTURA a circondare i dati che ci interesseranno.
8.  A questo punto lascio a chi legge il compito di far apparire anche i sospirati NOME, COGNOME ecc. nel pannello e di inserirne le coppie di segnali nei punti opportuni, ottenendo quanto indicato in figura:
   
   http://blog.shareoffice.it/giannigiaccaglini/gallery/image/898.aspx
   
9. Salvare il documento col nome che si vuole, verbi gratia FatturaConSchemaXML.docx.

Tale documento (o, meglio ancora, modello .dotm) presenta così delle coppie di tag  entro le quali l’utente può inserire i dati opportuni.

In gergo si parla di isola di dati inserita nel documento, che per il resto è un testo puro, più o meno intensamente formattato e dotato di figure e altri orpelli magari multimediali.

Il contenuto OOXML

Se ora eseguiamo le ben note manovre: modifica dell’estensione docx in zip e doppio clic sul file così rinominato – possiamo scoprirne i componenti, o “parti” OOXML. A noi interessa il document.xml posto  nella cartella Word, di cui riportiamo la sezione iniziale, segnando con evidenziatore – nella selva di nodi di testo normale e formati, tra cui quelli relativi alla tabella < w:tbl> e derivati - gli elementi < w:custom Xml> che ci interessano, unitamente ai nodi-figli < w:t> che racchiudano i vari dati dell’”isola”.

I molti omissis corrispondono a una selva di particolarità relative alla formattazione che sovrabbondano anche in una semplice letterina come quella esemplificata!

< w:customXml w:uri="http://www.w3.org/2001/XMLSchema" w:element="FATTURA">

  < w:p w:rsidR="00233072" w:rsidRDefault="00233072" w:rsidP="00A55353">

   < w:pPr>

   < w:r>

     < w:t xml:space="preserve">Spettabile< /w:t>

  < /w:r>

  < w:ind w:left="708" />

   < /w:pPr>

  < /w:p>

. . . o m i s s i s . . .

  < w:tblStyle w:val="Grigliatabella" />

 . . o m i s s i s . . .

  < w:tblBorders>

. . . o m i s s i s . . .

  < /w:tblBorders>

  < w:tblLook w:val="04A0" />

  < /w:tblPr>

  < w:tblGrid>

 . . o m i s s i s . . .

< /w:tblGrid>

  < w:tr w:rsidR="00233072" w:rsidTr="00233072">

  < w:customXml w:element="NOME">

  . . . o m i s s i s . . .

     < w:t>Giovanni< /w:t>

  . . . o m i s s i s . . .

  < /w:customXml>

  < w:customXml w:element="COGNOME">

  . . . o m i s s i s . . .

    < w:t>Rinaldi< /w:t>

. . . o m i s s i s . . .

  < /w:customXml>

  . . . o m i s s i s . . .

< /w:customXml>

Si osservi infine che l’ultima tag < /w:customXml> è la tag di chiusura del nodo iniziale, quello di attributi w:uri=”http://www.w3.org/2001/XMLSchema” e w:element="FATTURA", insomma la nostra sezione XML dal fantasioso nome FATTURA.

E una macro VBA per esplorarlo

A questo punto propongo una macro esplorativa ai più bravi che si cimentano col VBA dedicato alla gestione di documenti XML in generale e OOXML in particolare. Ripeto che un prerequisito è una certa familiarità con l’XPath (cercare questo tema su MSDN, Microsoft Developer Network e... meditare). Un altro prerequisito è la conoscenza dei file DOM e dei suoi vari oggetti che, in VBA, sono principalmente DOMDocument (il documento DOM, ovviamente), IXMLDOMNodeList (elenco di nodi) e IXMLDOMNode (singolo nodo). Per essi e per le loro proprietà e metodi non posso che invitare a leggere, chi non l’avesse fatto, i miei altri post e articoli su OOXML + VBA (dedicati a Excel: con Word si debbono solo tener presenti le diversità, tra cui il prefisso w: anteposto a nodi ecc., comunque le basi sono identiche).

Ma ecco i preliminari necessari.

1. Estrarre in una cartella di file, diciamo C:\MiaCartFattConSchemaXML i componenti del nostro FatturaConSchemaXML.docx, previa solita modifica dell’estensione in .zip.
2. Inserire in C:\MiaCartFattConSchemaXML un file Excel macro enabled, putacaso un GestioneCartFattConSchemaXML.xlsm;
3. Passare con Alt+F11 nell’Editor VBA e attivare la libreria Microsoft XML, v5, tramite Strumenti > Riferimenti... con quel che deve seguire;
4. In un Modulo1 dell’Editor VBA digitare la macro qui di seguito riportata.

Sub ElencaNodiDocumConSchema()

  ChDir ThisWorkbook.Path

  'MsgBox Dir("*.xml") 'servita per debug

  Dim DocXml As DOMDocument

  Dim NodiXml As IXMLDOMNodeList, NodoXml As IXMLDOMNode

  Set DocXml = New DOMDocument

  DocXml.async = False 'inibisce sincronizzazione DOM/origine

  DocXml.Load ("word\document.xml") 'carica il docum. DOM

  'Seleziona tutti i nodi-testo, per DEBUG

  'Set NodiXml = DocXml.SelectNodes("//w:t")

  'Seleziona i nodi relativi allo schema XML Fattura

  Dim strQyery As String

  strQuery = "//w:customXml//w:customXml"

  Set NodiXml = DocXml.SelectNodes(strQuery)

  Dim NumNodiTesto As Integer

  'NumNodiTesto = NodiXml.Length 'Per DEBUG

  'MsgBox "Numero nodi-testo: " & NumNodiTesto 'Per DEBUG

  Dim TuttoIlTesto As String

  Dim NomeCampo As string, DatoCampo As String

  For Each NodoXml In NodiXml

    i = i + 1

    NomeCampo = NodoXml.Attributes(0).Text

    DatoCampo = NodoXml.Text

    MsgBox "Nodo N. " & i & ":" & vbLf & _

    NomeCampo & " = " & DatoCampo

    TuttoIlTesto = TuttoIlTesto & " " & DatoCampo

  Next

  MsgBox TuttoIlTesto, vbInformation, _

  "Numero nodi-testo: " & NodiXml.Length

End Sub

Commenti essenziali. La Sub esordisce col rendere corrente la directory in cui giace il nostro file .xlsm, assieme alle parti della fattura con XML, poi carica il componente document.xml in un nuovo DOMDocument mediante DocXml.Load. Segue il (cruciale!) metodo SelectNodes del DocXml, che con opportuna sgtringa di query filtra tutti e soli i nodi facenti parte dello schema XML incorporato, ossia FATTURA. Questo, corrisponde alla tag più esterna w:custom Xml il cui w:element è = “FATTURA”, per l’appunto, al cui interno si danno diverse w:custom Xml il cui w:element è =”NOME”, “COGNOME” e così via. Pensa e ripensa (ce n’è voluta, confesso) la sospirata stringa è risultata "//w:customXml//w:customXml". Eureka! Funziona! Infatti il ciclo For Each NodoXml... Next emette chiari messaggi del tipo “Nodo N. 1: NOME = Giovanni”; “Nodo N. 2:COGNOME = Rinaldi”; eccetera.

Dimenticavo: il nome del campo, per i nodi interni del nodo FATTURA è il primo e unico attributo (w:element) mentre per FATTURA w:element è il secondo, il primo essendo w:uri. In pratica i nomi dei campi (della sequenza) sono dati dalla proprietà Attributes(0) (l’indice di Attributes parte con zero).

Altre macro per i più o meno esperti

Altro non voglio aggiungere, se non invitare a sperimentare altri esempi di query, che vado a fornire senza commenti. Il primo è dato dalla Sub seguente, in cui il filtro è “//w:t” che prende tutti i testi dei vari nodi, indiscriminatamente. Il confronto con la precedente macro è d’obbligo, direi!

Sub ElencaTestiDocumConSchema()

  ChDir ThisWorkbook.Path

  Dim DocXml As DOMDocument

  Dim NodiXml As IXMLDOMNodeList, NodoXml As IXMLDOMNode

  Set DocXml = New DOMDocument

  DocXml.async = False 'inibisce sincronizzazione DOM/origine

  DocXml.Load ("word\document.xml") 'carica il docum. DOM

  'Seleziona tutti i nodi-testo

  Set NodiXml = DocXml.SelectNodes("//w:t")

  Dim TuttoIlTesto As String

  Dim DatoCampo As String

  For Each NodoXml In NodiXml

    i = i + 1

    DatoCampo = NodoXml.Text

    MsgBox "Nodo N. " & i & ":" & vbLf & DatoCampo

    TuttoIlTesto = TuttoIlTesto & " " & DatoCampo

  Next

  ActiveCell = TuttoIlTesto ‘Testo completo nella cella attiva

  MsgBox TuttoIlTesto, vbInformation, "Numero nodi-testo: " & NodiXml.Length

End Sub

La variante seguente usa invece il filtro //w:element, per cui elenca tutti e soli i nomi dei vari campi.

Sub ElencaTuttiElementiDocumConSchema()

  ChDir ThisWorkbook.Path

  Dim DocXml As DOMDocument

  Dim NodiXml As IXMLDOMNodeList, NodoXml As IXMLDOMNode

  Set DocXml = New DOMDocument

  DocXml.async = False 'inibisce sincronizzazione DOM/origine

  DocXml.Load ("word\document.xml") 'carica il docum. DOM

  'Seleziona tutti gli attributi dei nodi dell’XML incorporato

  Set NodiXml = DocXml.SelectNodes("//@w:element")

  Dim TuttoIlTesto As String

  Dim NomeCampo As String

  For Each NodoXml In NodiXml

    i = i + 1

    NomeCampo = NodoXml.Text

    MsgBox "Nodo N. " & i & ":" & vbLf & NomeCampo

    TuttoIlTesto = TuttoIlTesto & " " & NomeCampo

  Next

  ActiveCell = TuttoIlTesto

  MsgBox TuttoIlTesto, vbInformation, "Numero nodi-testo: " & NodiXml.Length

End Sub

Si noterà che i nomi DESCRIZIONE, QUANT, PREZZO ecc. compaiono tante volte quante sono le voci della tabella “segnate” con tali tag dello schema. Inoltre stavolta compare anche FATTURA, il nome della tag più esterna, relativa all’intero schema applicato.

Chicca finale: somma di importi

Infine una routine che serve a totalizzare i dati del campo IMPORTO (scelta contingente, per semplicità e concretezza). È preceduta dalla funzione ValoreStringa, che traduce in valori i dati forniti dalla proprietà Text e torna utile anche in casi analoghi del mondo Word, ove (come nel documento d’esempio) non è raro che l’utente anteponga il simbolo dell’euro e utilizzi la virgola e il punto come separatori, mentre la funzione standard Val pretende il contrario e, inoltre, darebbe zero con stringhe come “€ 123” (darebbe 123 con “123 €”, ma tanto vale abolire tutti gli €).

Function ValoreStringa(ByVal StringaNum As String) As Double

  'Toglie l’eventuale € e i punti delle migliaia

  StringaNum = Replace(StringaNum, "€", "")

  StringaNum = Replace(StringaNum, ".", "")

  'Sostituisci la virgola col punto

  StringaNum = Replace(StringaNum, ",", ".")

  ValoreStringa = Val(StringaNum)

End Function

Sub SommaImporti()

  ChDir ThisWorkbook.Path

  Dim DocXml As DOMDocument

  Dim NodiXml As IXMLDOMNodeList, NodoXml As IXMLDOMNode

  Set DocXml = New DOMDocument

  DocXml.async = False

  DocXml.Load ("word\document.xml")

  Dim strQuery As String

  strQuery = "//w:customXml//w:customXml[@w:element='IMPORTO']"

  Set NodiXml = DocXml.SelectNodes(strQuery)

  Dim i As Integer, DatoCampo As String, Somma As Double

  For Each NodoXml In NodiXml

    i = i + 1

    DatoCampo = NodoXml.Text

    MsgBox "Nodo N. " & i & ":" & vbLf & DatoCampo

    Somma = Somma + ValoreStringa(DatoCampo)

  Next

  MsgBox "Importo totale = " & Somma

End Sub

Quanto a SommaImporti c’è solo da dire che la stringa di query, qui sopra evidenziata a dovere, filtra i soli nodi IMPORTO dello schema, che sono tanti quante sono le voci dell’ordine fatturato.